Newsgroup moderation tool developers guide

User post to a moderated newsgroup
|
|
v
------> ISC ---> look up moderator(s) email ----> Mail Server
							|
							v
moderator verify post  <---------------------------------
|
v
---> add "Approved" header and remove unnecessary headers
							|
							v							   
USENET server (authorized the moderator to post with approved header)

You may use the following script to download news post from your mail provider.

#!/usr/bin/perl

#    This is a program to download your mails to your local machine using
#    IMAP protocol.
#    Copyright (C) 2024 Salahuddin <salahuddin@member.fsf.org>
#
#    This program is free software: you can redistribute it and/or modify
#    it under the terms of the GNU General Public License as published by
#    the Free Software Foundation, either version 3 of the License, or
#    (at your option) any later version.
#
#    This program is distributed in the hope that it will be useful,
#    but WITHOUT ANY WARRANTY; without even the implied warranty of
#    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
#    GNU General Public License for more details.
#
#    You should have received a copy of the GNU General Public License
#    along with this program.  If not, see <https://www.gnu.org/licenses/>.

use strict;
use warnings;
use Net::IMAP::Client;
use Data::Dump qw(dump);

my $message_dir = 'YOU_USENET_MESSAGE_DIR';
my $noreply_mail = 'no-reply@your_domain';
my $send_rec_ack = 1;

sub parseFromAndSubject {
    my $message       = shift;
    my $from          = '';
    my $subject       = '';
    my @message_array = split(/\n/, $message);

    foreach(@message_array) {
	# first empty line
	if(/^$/) {
	    last;	    
	}
	if( /^From: / ) {
	    $from = $_;
	    $from=~ s/^From: //i;
	} elsif( /^Subject: / ) {
	    $subject = $_;
	    $subject =~ s/^Subject: //i;
	}
    }
    # trim
    $from =~ s/^\s+|\s+$//g;
    $subject =~ s/^\s+|\s+$//g;
    return ($from, $subject);
}


sub sendReceiveAck {
    my ($from, $subject) = @_;
    # configure your smart host
    system('echo "Submission received." | mail -s "Re: ' .  $subject . '" -r ' . $noreply_mail . ' \'' . $from . '\'');
}

my $imap = Net::IMAP::Client->new( 
    server => 'YOUR_MAIL_PROVIDER_HOST',
    user   => 'YOUR_MAIL_LOGIN',
    pass   => 'YOUR_MAIL_PASS',
    ssl    => 1,                               # (use SSL? default no)
    ssl_verify_peer => 1,                      # (use ca to verify server, default yes)
    #ssl_ca_file => '/etc/ssl/certs/certa.pm', # (CA file used for verify server) or
    #ssl_ca_path => '/etc/ssl/certs/',         # (CA path used for SSL)
    port   => 993                              # (but defaults are sane) 
) or die "Could not connect to IMAP server";

$imap->login or die('Login failed: ' . $imap->last_error);

my $dirctory_exists = 0;
my @folders = $imap->folders;
foreach(@folders) {
    if ($_ eq 'INBOX.PROCESSED') {
	$dirctory_exists = 1;
    }
}
if ($dirctory_exists eq 0) {
    $imap->create_folder('INBOX.PROCESSED');
}

# select folder
$imap->select('INBOX');

my $inbox = $imap->status('INBOX');

if ($inbox->{UNSEEN} >= 0) {
    # fetch all message ids (as array reference)
    my $messages = $imap->search('ALL');    
    foreach(@{$messages}) {
	my $message_id = $_;
	my $data = $imap->get_rfc822_body($message_id);

	my $message_number = time . $$;
	my $filename = $message_dir . $message_number . "_" . $message_id;

	open(FH, '>', $filename) or die $!;
	print FH $$data;
	close(FH);

	$imap->add_flags($message_id, '\\Seen');
	$imap->copy($message_id, 'INBOX.PROCESSED');
	$imap->add_flags($message_id, '\\Deleted');

	my $incoming_message = $$data;

	if ($send_rec_ack eq 1) {
	    my ($from, $subject) = parseFromAndSubject($incoming_message);
	    sendReceiveAck($from, $subject);
	}
    } 
}

$imap->expunge;

Thank you to Julien and Urs for their feedback in news.software.nntp