Add SameMajorVersionWithPreleases compat option to ecm_setup_version.

SameMajorVersionWithPreleases is intended implement the versioning
scheme followed by many KDE projects: minor releases after some high
number (eg: 90) are considered to be pre-releases of the next major
version, and are not compatible with the current major version. This
allows alpha and beta releases to be ordered correctly by
version-number-aware software like package managers (an alpha of version
2 should have a higher number than any release of version 1, but less
than version 2.0).

So a request for version 2.1.0 of a piece of software should not be
satisfied by 2.93.4, because that is actually a pre-release of version
3. On the other hand, a request for version 2.91.0 should be satisfied
by version 3.1.0.

Note that prereleases are not considered unless explicitly requested, so
2.93.4 will not satisfy requests for version 3 (or version 2) of a piece
of software.

2 files changed, 124 insertions, 6 deletions

diff --git a/modules/BasicConfigVersion-SameMajorVersionWithPrereleases.cmake.in b/modules/BasicConfigVersion-SameMajorVersionWithPrereleases.cmake.in
new file mode 100644
index 00000000..6d4e16f4
--- /dev/null
+++ b/modules/BasicConfigVersion-SameMajorVersionWithPrereleases.cmake.in
@@ -0,0 +1,64 @@
+# This is a basic version file for the Config-mode of find_package().
+# It is used by write_basic_package_version_file() as input file for configure_file()
+# to create a version-file which can be installed along a config.cmake file.
+#
+# The created file sets PACKAGE_VERSION_EXACT if the current version string and
+# the requested version string are exactly the same and it sets
+# PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version,
+# but only if the requested major version is the same as the current one EXCEPT
+# that all minor releases after (and including) @CVF_FIRST_PRERELEASE_VERSION@
+# are considered to be part of the next major release.
+#
+# The variables CVF_VERSION and CVF_FIRST_PRERELEASE_VERSION must be set before
+# calling configure_file().
+
+
+set(PACKAGE_VERSION "@CVF_VERSION@")
+
+if("${PACKAGE_VERSION}" VERSION_LESS "${PACKAGE_FIND_VERSION}" )
+  set(PACKAGE_VERSION_COMPATIBLE FALSE)
+else()
+
+  if("@CVF_VERSION@" MATCHES "^([0-9]+)\\.([0-9]+)(\\.|$)")
+    set(CVF_VERSION_MAJOR "${CMAKE_MATCH_1}")
+    set(CVF_VERSION_MINOR "${CMAKE_MATCH_2}")
+  else()
+    set(CVF_VERSION_MAJOR "@CVF_VERSION@")
+    set(CVF_VERSION_MINOR "0")
+  endif()
+
+  set(_real_version_major "${CVF_VERSION_MAJOR}")
+  if(NOT "${CVF_VERSION_MINOR}" LESS "@CVF_FIRST_PRERELEASE_VERSION@")
+    math(EXPR _real_version_major "${CVF_VERSION_MAJOR}+1")
+  endif()
+
+  set(_real_find_version_major "${PACKAGE_FIND_VERSION_MAJOR}")
+  if("${PACKAGE_FIND_VERSION_COUNT}" GREATER 1)
+    if(NOT "${PACKAGE_FIND_VERSION_MINOR}" LESS "@CVF_FIRST_PRERELEASE_VERSION@")
+      math(EXPR _real_find_version_major "${PACKAGE_FIND_VERSION_MAJOR}+1")
+    endif()
+  endif()
+
+  if("${_real_find_version_major}" STREQUAL "${_real_version_major}")
+    set(PACKAGE_VERSION_COMPATIBLE TRUE)
+  else()
+    set(PACKAGE_VERSION_COMPATIBLE FALSE)
+  endif()
+
+  if( "${PACKAGE_FIND_VERSION}" STREQUAL "${PACKAGE_VERSION}")
+      set(PACKAGE_VERSION_EXACT TRUE)
+  endif()
+endif()
+
+
+# if the installed or the using project don't have CMAKE_SIZEOF_VOID_P set, ignore it:
+if("${CMAKE_SIZEOF_VOID_P}"  STREQUAL ""  OR "@CMAKE_SIZEOF_VOID_P@" STREQUAL "")
+   return()
+endif()
+
+# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
+if(NOT "${CMAKE_SIZEOF_VOID_P}" STREQUAL "@CMAKE_SIZEOF_VOID_P@")
+  math(EXPR installedBits "@CMAKE_SIZEOF_VOID_P@ * 8")
+  set(PACKAGE_VERSION "${PACKAGE_VERSION} (${installedBits}bit)")
+  set(PACKAGE_VERSION_UNSUITABLE TRUE)
+endif()
diff --git a/modules/ECMSetupVersion.cmake b/modules/ECMSetupVersion.cmake
index b908f96e..5f738c53 100644
--- a/modules/ECMSetupVersion.cmake
+++ b/modules/ECMSetupVersion.cmake
@@ -10,7 +10,9 @@
 #                     VARIABLE_PREFIX <prefix>
 #                     [SOVERSION <soversion>]
 #                     [VERSION_HEADER <filename>]
-#                     [PACKAGE_VERSION_FILE <filename> [COMPATIBILITY <compat>]] )
+#                     [PACKAGE_VERSION_FILE <filename>
+#                           [COMPATIBILITY <compat>
+#                               [FIRST_PRERELEASE_VERSION <prerelease_version>]]] )
 #
 # This parses a version string and sets up a standard set of version variables.
 # It can optionally also create a C version header file and a CMake package
@@ -55,9 +57,20 @@
 # file is created using the write_basic_package_version_file() macro provided by
 # CMake. It should be installed in the same location as the Config.cmake file of
 # the library so that it can be found by find_package().  If the filename is a
-# relative path, it is interpreted as relative to CMAKE_CURRENT_BINARY_DIR. The
-# optional COMPATIBILITY option is forwarded to
-# write_basic_package_version_file(), and defaults to AnyNewerVersion.
+# relative path, it is interpreted as relative to CMAKE_CURRENT_BINARY_DIR.
+#
+# The optional COMPATIBILITY option is similar to that accepted by
+# write_basic_package_version_file(), except that it defaults to
+# AnyNewerVersion if it is omitted, and it also accepts
+# ``SameMajorVersionWithPrereleases`` as a value, in which case the
+# ``FIRST_PRERELEASE_VERSION`` option must also be given. This versioning
+# system behaves like SameMajorVersion, except that it treats all x.y releases,
+# where y is at least ``<prerelease_version>``, as (x+1) releases. So if
+# ``<prerelease_version>`` is 90, a request for version 2.90.0 will be satisfied
+# by 3.1.0, while a request for 2.89.0 will not be. Note that in this scenario,
+# version 2.90.0 of the software will not satisfy requests for version 2, version
+# version 2.1.1 *or* version 3 of the software, as prereleases are not considered
+# unless explicitly requested.
 #
 # If CMake policy CMP0048 is NEW, an alternative form of the command is
 # available::
@@ -93,10 +106,47 @@ include(CMakePackageConfigHelpers)
 # save the location of the header template while CMAKE_CURRENT_LIST_DIR
 # has the value we want
 set(_ECM_SETUP_VERSION_HEADER_TEMPLATE "${CMAKE_CURRENT_LIST_DIR}/ECMVersionHeader.h.in")
+set(_ECM_PACKAGE_VERSION_TEMPLATE_DIR "${CMAKE_CURRENT_LIST_DIR}")
+
+# like write_basic_package_version_file from CMake, but
+# looks for our template files as well
+function(ecm_write_package_version_file _filename)
+  set(options )
+  set(oneValueArgs VERSION COMPATIBILITY FIRST_PRERELEASE_VERSION)
+  set(multiValueArgs )
+
+  cmake_parse_arguments(CVF "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  if(CVF_UNPARSED_ARGUMENTS)
+      message(FATAL_ERROR "Unknown keywords given to ecm_write_basic_package_version_file(): \"${CVF_UNPARSED_ARGUMENTS}\"")
+  endif()
+
+  set(versionTemplateFile "${_ECM_PACKAGE_VERSION_TEMPLATE_DIR}/BasicConfigVersion-${CVF_COMPATIBILITY}.cmake.in")
+  if(NOT EXISTS "${versionTemplateFile}")
+      write_basic_package_version_file("${_filename}" VERSION "${CVF_VERSION}" COMPATIBILITY "${CVF_COMPATIBILITY}")
+      return()
+  endif()
+
+  if("${CVF_COMPATIBILITY}" STREQUAL "SameMajorVersionWithPrereleases")
+      if("${CVF_FIRST_PRERELEASE_VERSION}" STREQUAL "")
+          message(FATAL_ERROR "No FIRST_PRERELEASE_VERSION specified for ecm_write_basic_package_version_file()")
+      endif()
+  endif()
+
+  if("${CVF_VERSION}" STREQUAL "")
+      if ("${PROJECT_VERSION}" STREQUAL "")
+          message(FATAL_ERROR "No VERSION specified for ecm_write_basic_package_version_file()")
+      else()
+          set(CVF_VERSION "${PROJECT_VERSION}")
+      endif()
+  endif()
+
+  configure_file("${versionTemplateFile}" "${_filename}" @ONLY)
+endfunction()
 
 function(ecm_setup_version _version)
     set(options )
-    set(oneValueArgs VARIABLE_PREFIX SOVERSION VERSION_HEADER PACKAGE_VERSION_FILE COMPATIBILITY)
+    set(oneValueArgs VARIABLE_PREFIX SOVERSION VERSION_HEADER PACKAGE_VERSION_FILE COMPATIBILITY FIRST_PRERELEASE_VERSION)
     set(multiValueArgs )
 
     cmake_parse_arguments(ESV "${options}" "${oneValueArgs}" "${multiValueArgs}"  ${ARGN})
@@ -180,7 +230,11 @@ function(ecm_setup_version _version)
         if(NOT ESV_COMPATIBILITY)
             set(ESV_COMPATIBILITY AnyNewerVersion)
         endif()
-        write_basic_package_version_file("${ESV_PACKAGE_VERSION_FILE}" VERSION ${_version} COMPATIBILITY ${ESV_COMPATIBILITY})
+        ecm_write_package_version_file("${ESV_PACKAGE_VERSION_FILE}"
+            VERSION ${_version}
+            COMPATIBILITY ${ESV_COMPATIBILITY}
+            FIRST_PRERELEASE_VERSION "${ESV_FIRST_PRERELEASE_VERSION}"
+            )
     endif()
 
     if(should_set_prefixed_vars)