Add a module to provide an uninstall target.

This is basically just the code available on the CMake FAQ item about
`make uninstall`, but packaged up in a convenient module.

REVIEW: 122359

2 files changed, 77 insertions, 0 deletions

diff --git a/modules/ECMUninstallTarget.cmake b/modules/ECMUninstallTarget.cmake
new file mode 100644
index 00000000..d9363125
--- /dev/null
+++ b/modules/ECMUninstallTarget.cmake
@@ -0,0 +1,56 @@
+#.rst:
+# ECMUninstallTarget
+# ------------------
+#
+# Add an ``uninstall`` target.
+#
+# By including this module, an ``uninstall`` target will be added to your CMake
+# project. This will remove all files installed (or updated) by a previous
+# invocation of the ``install`` target. It will not remove files created or
+# modified by an ``install(SCRIPT)`` or ``install(CODE)`` command; you should
+# create a custom uninstallation target for these and use ``add_dependency`` to
+# make the ``uninstall`` target depend on it:
+#
+# .. code-block:: cmake
+#
+#   include(ECMUninstallTarget)
+#   install(SCRIPT install-foo.cmake)
+#   add_custom_target(uninstall_foo COMMAND ${CMAKE_COMMAND} -P uninstall-foo.cmake)
+#   add_dependency(uninstall uninstall_foo)
+#
+# The target will fail if the ``install`` target has not yet been run (so it is
+# not possible to run CMake on the project and then immediately run the
+# ``uninstall`` target).
+#
+# .. warning::
+#
+#   CMake deliberately does not provide an ``uninstall`` target by default on
+#   the basis that such a target has the potential to remove important files
+#   from a user's computer. Use with caution.
+
+#=============================================================================
+# Copyright 2015 Alex Merry <alex.merry@kde.org>
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file COPYING-CMAKE-SCRIPTS for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of extra-cmake-modules, substitute the full
+#  License text for the above reference.)
+
+if (NOT TARGET uninstall)
+    configure_file(
+        "${CMAKE_CURRENT_LIST_DIR}/ecm_uninstall.cmake.in"
+        "${CMAKE_BINARY_DIR}/ecm_uninstall.cmake"
+        IMMEDIATE
+        @ONLY
+    )
+
+    add_custom_target(uninstall
+        COMMAND "${CMAKE_COMMAND}" -P "${CMAKE_BINARY_DIR}/ecm_uninstall.cmake"
+        WORKING_DIRECTORY "${CMAKE_BINARY_DIR}"
+    )
+endif()
diff --git a/modules/ecm_uninstall.cmake.in b/modules/ecm_uninstall.cmake.in
new file mode 100644
index 00000000..d0cf1241
--- /dev/null
+++ b/modules/ecm_uninstall.cmake.in
@@ -0,0 +1,21 @@
+if(NOT EXISTS "@CMAKE_BINARY_DIR@/install_manifest.txt")
+    message(FATAL_ERROR "Cannot find install manifest: @CMAKE_BINARY_DIR@/install_manifest.txt")
+endif()
+
+file(READ "@CMAKE_BINARY_DIR@/install_manifest.txt" files)
+string(REGEX REPLACE "\n" ";" files "${files}")
+foreach(file ${files})
+    message(STATUS "Uninstalling $ENV{DESTDIR}${file}")
+    if(IS_SYMLINK "$ENV{DESTDIR}${file}" OR EXISTS "$ENV{DESTDIR}${file}")
+        exec_program(
+            "@CMAKE_COMMAND@" ARGS "-E remove \"$ENV{DESTDIR}${file}\""
+            OUTPUT_VARIABLE rm_out
+            RETURN_VALUE rm_retval
+            )
+        if(NOT "${rm_retval}" STREQUAL 0)
+            message(FATAL_ERROR "Problem when removing $ENV{DESTDIR}${file}")
+        endif(NOT "${rm_retval}" STREQUAL 0)
+    else()
+        message(STATUS "File $ENV{DESTDIR}${file} does not exist.")
+    endif()
+endforeach()