Now into kdelibs as kdebase and koffice use them

svn path=/trunk/KDE/kdelibs/; revision=564569

2 files changed, 98 insertions, 0 deletions

diff --git a/modules/FindFontconfig.cmake b/modules/FindFontconfig.cmake
new file mode 100644
index 00000000..541b20d8
--- /dev/null
+++ b/modules/FindFontconfig.cmake
@@ -0,0 +1,55 @@
+# - Try to find the  Fontconfig
+# Once done this will define
+#
+#  FONTCONFIG_FOUND - system has Fontconfig
+#  FONTCONFIG_LIBRARIES - Link these to use FONTCONFIG
+#  FONTCONFIG_DEFINITIONS - Compiler switches required for using FONTCONFIG
+#
+
+if (FONTCONFIG_LIBRARIES AND FONTCONFIG_DEFINITIONS)
+
+  # in cache already
+  set(FONTCONFIG_FOUND TRUE)
+
+else (FONTCONFIG_LIBRARIES AND FONTCONFIG_DEFINITIONS)
+
+  # use pkg-config to get the directories and then use these values
+  # in the FIND_PATH() and FIND_LIBRARY() calls
+  INCLUDE(UsePkgConfig)
+  
+  PKGCONFIG(fontconfig _FONTCONFIGIncDir _FONTCONFIGLinkDir _FONTCONFIGLinkFlags _FONTCONFIGCflags)
+
+  set(FONTCONFIG_DEFINITIONS ${_FONTCONFIGCflags} CACHE INTERNAL "The compilation flags for fontconfig")
+
+  find_path(FONTCONFIG_INCLUDE_DIR fontconfig/fontconfig.h
+    PATHS
+    ${_FONTCONFIGIncDir}
+    /usr/include
+    /usr/local/include
+    /usr/X11/include
+  )
+
+  find_library(FONTCONFIG_LIBRARIES NAMES fontconfig
+    PATHS
+    ${_FONTCONFIGLinkDir}
+    /usr/lib
+    /usr/local/lib
+  )
+
+  if (FONTCONFIG_LIBRARIES)
+     set(FONTCONFIG_FOUND TRUE)
+  endif (FONTCONFIG_LIBRARIES)
+
+  if (FONTCONFIG_FOUND)
+    if (NOT FONTCONFIG_FIND_QUIETLY)
+      message(STATUS "Found FONTCONFIG: ${FONTCONFIG_LIBRARIES}")
+    endif (NOT FONTCONFIG_FIND_QUIETLY)
+  else (FONTCONFIG_FOUND)
+    if (FONTCONFIG_FIND_REQUIRED)
+      message(FATAL_ERROR "Could NOT find FONTCONFIG")
+    endif (FONTCONFIG_FIND_REQUIRED)
+  endif (FONTCONFIG_FOUND)
+
+  MARK_AS_ADVANCED(FONTCONFIG_LIBRARIES)
+
+endif (FONTCONFIG_LIBRARIES AND FONTCONFIG_DEFINITIONS)
diff --git a/modules/FindFreetype.cmake b/modules/FindFreetype.cmake
new file mode 100644
index 00000000..8a11dc40
--- /dev/null
+++ b/modules/FindFreetype.cmake
@@ -0,0 +1,43 @@
+# - Try to find the freetype library
+# Once done this will define
+#
+#  FREETYPE_FOUND - system has Fontconfig
+#  FREETYPE_INCLUDE_DIR - the FONTCONFIG include directory
+#  FREETYPE_LIBRARIES - Link these to use FREETYPE
+#
+
+if (FREETYPE_LIBRARIES AND FREETYPE_INCLUDE_DIR)
+
+  # in cache already
+  set(FREETYPE_FOUND TRUE)
+
+else (FREETYPE_LIBRARIES AND FREETYPE_INCLUDE_DIR)
+
+  FIND_PROGRAM(FREETYPECONFIG_EXECUTABLE NAMES freetype-config PATHS
+     /usr/bin
+     /usr/local/bin
+     /opt/local/bin
+  )
+
+  #reset vars
+  set(FREETYPE_LIBRARIES)
+  set(FREETYPE_INCLUDE_DIR)
+
+  # if freetype-config has been found
+  if(FREETYPECONFIG_EXECUTABLE)
+
+    EXEC_PROGRAM(${FREETYPECONFIG_EXECUTABLE} ARGS --libs RETURN_VALUE _return_VALUE OUTPUT_VARIABLE FREETYPE_LIBRARIES)
+
+    EXEC_PROGRAM(${FREETYPECONFIG_EXECUTABLE} ARGS --cflags RETURN_VALUE _return_VALUE OUTPUT_VARIABLE FREETYPE_INCLUDE_DIR)
+    if(FREETYPE_LIBRARIES AND FREETYPE_INCLUDE_DIR)
+      set(FREETYPE_FOUND TRUE)
+      #message(STATUS "Found freetype: ${FREETYPE_LIBRARIES}")
+    endif(FREETYPE_LIBRARIES AND FREETYPE_INCLUDE_DIR)
+
+    MARK_AS_ADVANCED(FREETYPE_LIBRARIES FREETYPE_INCLUDE_DIR)
+
+    set( FREETYPE_LIBRARIES ${FREETYPE_LIBRARIES} CACHE INTERNAL "The libraries for freetype" )
+
+  endif(FREETYPECONFIG_EXECUTABLE)
+
+endif (FREETYPE_LIBRARIES AND FREETYPE_INCLUDE_DIR)