blob: 08221d43b7db7e5c77c1cc2082ee7ed487301d40 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
#.rst:
# FindGradle
# ----------
#
# Provides the ability to build Android AAR libraries using Gradle.
#
# This relies on the Qt provided Gradle, so a Qt for Android installation
# is required.
#
# gradle_add_aar(<target>
# BUIDLFILE build.gradle
# NAME <aar-name>)
#
# This builds an Android AAR library using the given ``build.gradle`` file.
#
# gradle_install_aar(<target>
# DESTINATION <dest>)
#
# Installs a Android AAR library that has been created with ``gradle_add_aar``.
#
# Since 5.76.0.
#=============================================================================
# SPDX-FileCopyrightText: 2019 Volker Krause <vkrause@kde.org>
#
# SPDX-License-Identifier: BSD-3-Clause
#=============================================================================
include(CMakeParseArguments)
include(FindPackageHandleStandardArgs)
find_package(Qt5Core REQUIRED)
if (NOT WIN32)
set(Gradle_EXECUTABLE ${CMAKE_BINARY_DIR}/gradle/gradlew)
else()
set(Gradle_EXECUTABLE ${CMAKE_BINARY_DIR}/gradle/gradlew.bat)
endif()
get_target_property(_qt_core_location Qt5::Core LOCATION)
get_filename_component(_qt_install_root ${_qt_core_location} DIRECTORY)
get_filename_component(_qt_install_root ${_qt_install_root}/../ ABSOLUTE)
set(_gradle_template_dir ${CMAKE_CURRENT_LIST_DIR})
add_custom_command(OUTPUT ${Gradle_EXECUTABLE}
COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/gradle
COMMAND ${CMAKE_COMMAND} -E copy_directory ${_qt_install_root}/src/3rdparty/gradle ${CMAKE_BINARY_DIR}/gradle
)
add_custom_target(gradle DEPENDS ${Gradle_EXECUTABLE})
find_package_handle_standard_args(Gradle DEFAULT_MSG Gradle_EXECUTABLE)
function(gradle_add_aar target)
cmake_parse_arguments(ARG "" "BUILDFILE;NAME" "" ${ARGN})
set(_build_root ${CMAKE_CURRENT_BINARY_DIR}/gradle_build/${ARG_NAME})
configure_file(${_gradle_template_dir}/local.properties.cmake ${_build_root}/local.properties)
configure_file(${_gradle_template_dir}/settings.gradle.cmake ${_build_root}/settings.gradle)
configure_file(${ARG_BUILDFILE} ${_build_root}/build.gradle)
if (CMAKE_BUILD_TYPE MATCHES "[Dd][Ee][Bb][Uu][Gg]")
set(_aar_suffix "-debug")
set(_aar_gradleCmd "assembleDebug")
else()
set(_aar_suffix "-release")
set(_aar_gradleCmd "assembleRelease")
endif()
file(GLOB_RECURSE _src_files CONFIGURE_DEPENDS "*")
add_custom_command(
OUTPUT ${_build_root}/build/outputs/aar/${ARG_NAME}${_aar_suffix}.aar
COMMAND ${Gradle_EXECUTABLE} ${_aar_gradleCmd}
DEPENDS ${Gradle_EXECUTABLE} ${_src_files}
DEPENDS gradle
WORKING_DIRECTORY ${_build_root}
)
add_custom_target(${target} ALL DEPENDS ${_build_root}/build/outputs/aar/${ARG_NAME}${_aar_suffix}.aar)
set_target_properties(${target} PROPERTIES LOCATION ${_build_root}/build/outputs/aar/${ARG_NAME}${_aar_suffix}.aar)
set_target_properties(${target} PROPERTIES OUTPUT_NAME ${ARG_NAME})
endfunction()
function(gradle_install_aar target)
cmake_parse_arguments(ARG "" "DESTINATION" "" ${ARGN})
get_target_property(_loc ${target} LOCATION)
get_target_property(_name ${target} OUTPUT_NAME)
install(FILES ${_loc} DESTINATION ${ARG_DESTINATION} RENAME ${_name}.aar)
endfunction()
|
