Make ecm_setup_version interact well with CMP0048

When CMake policy CMP0048 (CMake 3.0) is set to NEW, the project()
command is meant to manage the project's version variables. We therefore
do not set the PROJECT_VERSION variables in this case.

To make sure projects do not have to specify their version in multiple
places, this also allows the keyword "PROJECT" to be passed to
ecm_setup_version instead of an actual version number. In this case, the
version passed to project() will be used.

REVIEW: 117619

2 files changed, 105 insertions, 33 deletions

diff --git a/modules/ECMSetupVersion.cmake b/modules/ECMSetupVersion.cmake
index 3ae6fa8f..aff17de6 100644
--- a/modules/ECMSetupVersion.cmake
+++ b/modules/ECMSetupVersion.cmake
@@ -23,12 +23,18 @@
 #   <prefix>_VERSION_MAJOR  - <major>
 #   <prefix>_VERSION_MINOR  - <minor>
 #   <prefix>_VERSION_PATCH  - <patch>
-#   <prefix>_VERSION_STRING - <version>
+#   <prefix>_VERSION        - <version>
+#   <prefix>_VERSION_STRING - <version> (for compatibility: use <prefix>_VERSION instead)
 #   <prefix>_SOVERSION      - <soversion>, or <major> if SOVERSION was not given
+#
+# If CMake policy CMP0048 is not NEW, the following CMake variables will also
+# be set:
+#
 #   PROJECT_VERSION_MAJOR   - <major>
 #   PROJECT_VERSION_MINOR   - <minor>
 #   PROJECT_VERSION_PATCH   - <patch>
-#   PROJECT_VERSION_STRING  - <version>
+#   PROJECT_VERSION         - <version>
+#   PROJECT_VERSION_STRING  - <version> (for compatibility: use PROJECT_VERSION instead)
 #
 # If the VERSION_HEADER option is used, a simple C header is generated with the
 # given filename. If filename is a relative path, it is interpreted as relative
@@ -50,8 +56,24 @@
 # CMake. It should be installed in the same location as the Config.cmake file of
 # the library so that it can be found by find_package().  If the filename is a
 # relative path, it is interpreted as relative to CMAKE_CURRENT_BINARY_DIR.
+#
+# If CMake policy CMP0048 is NEW, an alternative form of the command is
+# available::
+#
+#   ecm_setup_version(PROJECT
+#                     [VARIABLE_PREFIX <prefix>]
+#                     [SOVERSION <soversion>]
+#                     [VERSION_HEADER <filename>]
+#                     [PACKAGE_VERSION_FILE <filename>] )
+#
+# This will use the version information set by the project() command.
+# VARIABLE_PREFIX defaults to the project name.  Note that PROJECT must be the
+# first argument.  In all other respects, it behaves like the other form of the
+# command.
+#
 
 #=============================================================================
+# Copyright 2014 Alex Merry <alex.merry@kde.org>
 # Copyright 2012 Alexander Neundorf <neundorf@kde.org>
 #
 # Distributed under the OSI-approved BSD License (the "License");
@@ -64,10 +86,12 @@
 # (To distribute this file outside of extra-cmake-modules, substitute the full
 #  License text for the above reference.)
 
-# FIXME: Figure out how this should interact with CMP0048 in CMake 3.0.0
-
 include(CMakePackageConfigHelpers)
 
+# save the location of the header template while CMAKE_CURRENT_LIST_DIR
+# has the value we want
+set(_ECM_SETUP_VERSION_HEADER_TEMPLATE "${CMAKE_CURRENT_LIST_DIR}/ECMVersionHeader.h.in")
+
 function(ECM_SETUP_VERSION _version)
   set(options )
   set(oneValueArgs VARIABLE_PREFIX SOVERSION VERSION_HEADER PACKAGE_VERSION_FILE)
@@ -79,47 +103,95 @@ function(ECM_SETUP_VERSION _version)
     message(FATAL_ERROR "Unknown keywords given to ECM_SETUP_VERSION(): \"${ESV_UNPARSED_ARGUMENTS}\"")
   endif()
 
+  set(project_manages_version FALSE)
+  set(use_project_version FALSE)
+  cmake_policy(GET CMP0048 project_version_policy)
+  if(project_version_policy STREQUAL "NEW")
+    set(project_manages_version TRUE)
+    if(_version STREQUAL "PROJECT")
+      set(use_project_version TRUE)
+    endif()
+  elseif(_version STREQUAL "PROJECT")
+    message(FATAL_ERROR "ecm_setup_version given PROJECT argument, but CMP0048 is not NEW")
+  endif()
+
+  set(should_set_prefixed_vars TRUE)
   if(NOT ESV_VARIABLE_PREFIX)
-    message(FATAL_ERROR "Required argument PREFIX missing in ECM_SETUP_VERSION() call")
+    if(use_project_version)
+      set(ESV_VARIABLE_PREFIX "${PROJECT_NAME}")
+      set(should_set_prefixed_vars FALSE)
+    else()
+      message(FATAL_ERROR "Required argument PREFIX missing in ECM_SETUP_VERSION() call")
+    endif()
   endif()
 
-  string(REGEX REPLACE "^([0-9]+)\\.[0-9]+\\.[0-9]+.*" "\\1" _major "${_version}")
-  string(REGEX REPLACE "^[0-9]+\\.([0-9]+)\\.[0-9]+.*" "\\1" _minor "${_version}")
-  string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+).*" "\\1" _patch "${_version}")
+  if(use_project_version)
+    set(_version "${PROJECT_VERSION}")
+    set(_major "${PROJECT_VERSION_MAJOR}")
+    set(_minor "${PROJECT_VERSION_MINOR}")
+    set(_patch "${PROJECT_VERSION_PATCH}")
+  else()
+    string(REGEX REPLACE "^([0-9]+)\\.[0-9]+\\.[0-9]+.*" "\\1" _major "${_version}")
+    string(REGEX REPLACE "^[0-9]+\\.([0-9]+)\\.[0-9]+.*" "\\1" _minor "${_version}")
+    string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+).*" "\\1" _patch "${_version}")
+  endif()
 
   if(NOT ESV_SOVERSION)
     set(ESV_SOVERSION ${_major})
   endif()
 
-  set(${ESV_VARIABLE_PREFIX}_VERSION_MAJOR ${_major})
-  set(${ESV_VARIABLE_PREFIX}_VERSION_MINOR ${_minor})
-  set(${ESV_VARIABLE_PREFIX}_VERSION_PATCH ${_patch})
+  if(should_set_prefixed_vars)
+    set(${ESV_VARIABLE_PREFIX}_VERSION "${_version}")
+    set(${ESV_VARIABLE_PREFIX}_VERSION_MAJOR ${_major})
+    set(${ESV_VARIABLE_PREFIX}_VERSION_MINOR ${_minor})
+    set(${ESV_VARIABLE_PREFIX}_VERSION_PATCH ${_patch})
+  endif()
+
   set(${ESV_VARIABLE_PREFIX}_SOVERSION ${ESV_SOVERSION})
-  set(${ESV_VARIABLE_PREFIX}_VERSION_STRING "${_version}")
 
-  set(PROJECT_VERSION_STRING "${${ESV_VARIABLE_PREFIX}_VERSION_STRING}")
-  set(PROJECT_VERSION_MAJOR "${${ESV_VARIABLE_PREFIX}_VERSION_MAJOR}")
-  set(PROJECT_VERSION_MINOR "${${ESV_VARIABLE_PREFIX}_VERSION_MINOR}")
-  set(PROJECT_VERSION_PATCH "${${ESV_VARIABLE_PREFIX}_VERSION_PATCH}")
+  if(NOT project_manages_version)
+    set(PROJECT_VERSION "${_version}")
+    set(PROJECT_VERSION_MAJOR "${_major}")
+    set(PROJECT_VERSION_MINOR "${_minor}")
+    set(PROJECT_VERSION_PATCH "${_patch}")
+  endif()
+
+  # compat
+  set(PROJECT_VERSION_STRING "${PROJECT_VERSION}")
+  set(${ESV_VARIABLE_PREFIX}_VERSION_STRING "${${ESV_VARIABLE_PREFIX}_VERSION}")
 
   if(ESV_VERSION_HEADER)
-    set(PROJECT_NAME_UPPER "${ESV_VARIABLE_PREFIX}")
-    configure_file("${ECM_MODULE_DIR}/ECMVersionHeader.h.in" "${ESV_VERSION_HEADER}")
+    set(HEADER_PREFIX "${ESV_VARIABLE_PREFIX}")
+    set(HEADER_VERSION "${_version}")
+    set(HEADER_VERSION_MAJOR "${_major}")
+    set(HEADER_VERSION_MINOR "${_minor}")
+    set(HEADER_VERSION_PATCH "${_patch}")
+    configure_file("${_ECM_SETUP_VERSION_HEADER_TEMPLATE}" "${ESV_VERSION_HEADER}")
   endif()
 
   if(ESV_PACKAGE_VERSION_FILE)
     write_basic_package_version_file("${ESV_PACKAGE_VERSION_FILE}" VERSION ${_version} COMPATIBILITY AnyNewerVersion)
   endif()
 
-  set(${ESV_VARIABLE_PREFIX}_VERSION_MAJOR  "${${ESV_VARIABLE_PREFIX}_VERSION_MAJOR}"  PARENT_SCOPE)
-  set(${ESV_VARIABLE_PREFIX}_VERSION_MINOR  "${${ESV_VARIABLE_PREFIX}_VERSION_MINOR}"  PARENT_SCOPE)
-  set(${ESV_VARIABLE_PREFIX}_VERSION_PATCH  "${${ESV_VARIABLE_PREFIX}_VERSION_PATCH}"  PARENT_SCOPE)
-  set(${ESV_VARIABLE_PREFIX}_SOVERSION      "${${ESV_VARIABLE_PREFIX}_SOVERSION}"      PARENT_SCOPE)
-  set(${ESV_VARIABLE_PREFIX}_VERSION_STRING "${${ESV_VARIABLE_PREFIX}_VERSION_STRING}" PARENT_SCOPE)
+  if(should_set_prefixed_vars)
+    set(${ESV_VARIABLE_PREFIX}_VERSION_MAJOR "${${ESV_VARIABLE_PREFIX}_VERSION_MAJOR}" PARENT_SCOPE)
+    set(${ESV_VARIABLE_PREFIX}_VERSION_MINOR "${${ESV_VARIABLE_PREFIX}_VERSION_MINOR}" PARENT_SCOPE)
+    set(${ESV_VARIABLE_PREFIX}_VERSION_PATCH "${${ESV_VARIABLE_PREFIX}_VERSION_PATCH}" PARENT_SCOPE)
+    set(${ESV_VARIABLE_PREFIX}_VERSION       "${${ESV_VARIABLE_PREFIX}_VERSION}"       PARENT_SCOPE)
+  endif()
+
+  # always set the soversion
+  set(${ESV_VARIABLE_PREFIX}_SOVERSION "${${ESV_VARIABLE_PREFIX}_SOVERSION}" PARENT_SCOPE)
+
+  if(NOT project_manages_version)
+    set(PROJECT_VERSION       "${PROJECT_VERSION}"       PARENT_SCOPE)
+    set(PROJECT_VERSION_MAJOR "${PROJECT_VERSION_MAJOR}" PARENT_SCOPE)
+    set(PROJECT_VERSION_MINOR "${PROJECT_VERSION_MINOR}" PARENT_SCOPE)
+    set(PROJECT_VERSION_PATCH "${PROJECT_VERSION_PATCH}" PARENT_SCOPE)
+  endif()
 
+  # always set the compatibility variables
   set(PROJECT_VERSION_STRING "${PROJECT_VERSION_STRING}" PARENT_SCOPE)
-  set(PROJECT_VERSION_MAJOR  "${PROJECT_VERSION_MAJOR}"  PARENT_SCOPE)
-  set(PROJECT_VERSION_MINOR  "${PROJECT_VERSION_MINOR}"  PARENT_SCOPE)
-  set(PROJECT_VERSION_PATCH  "${PROJECT_VERSION_PATCH}"  PARENT_SCOPE)
+  set(${ESV_VARIABLE_PREFIX}_VERSION_STRING "${${ESV_VARIABLE_PREFIX}_VERSION}" PARENT_SCOPE)
 
 endfunction()
diff --git a/modules/ECMVersionHeader.h.in b/modules/ECMVersionHeader.h.in
index 19eb96c5..ee033cd2 100644
--- a/modules/ECMVersionHeader.h.in
+++ b/modules/ECMVersionHeader.h.in
@@ -1,11 +1,11 @@
 
-#ifndef @PROJECT_NAME_UPPER@_VERSION_H
-#define @PROJECT_NAME_UPPER@_VERSION_H
+#ifndef @HEADER_PREFIX@_VERSION_H
+#define @HEADER_PREFIX@_VERSION_H
 
-#define @PROJECT_NAME_UPPER@_VERSION_STRING "@PROJECT_VERSION_STRING@"
-#define @PROJECT_NAME_UPPER@_VERSION_MAJOR @PROJECT_VERSION_MAJOR@
-#define @PROJECT_NAME_UPPER@_VERSION_MINOR @PROJECT_VERSION_MINOR@
-#define @PROJECT_NAME_UPPER@_VERSION_PATCH @PROJECT_VERSION_PATCH@
-#define @PROJECT_NAME_UPPER@_VERSION ((@PROJECT_VERSION_MAJOR@<<16)|(@PROJECT_VERSION_MINOR@<<8)|(@PROJECT_VERSION_PATCH@))
+#define @HEADER_PREFIX@_VERSION_STRING "@HEADER_VERSION@"
+#define @HEADER_PREFIX@_VERSION_MAJOR @HEADER_VERSION_MAJOR@
+#define @HEADER_PREFIX@_VERSION_MINOR @HEADER_VERSION_MINOR@
+#define @HEADER_PREFIX@_VERSION_PATCH @HEADER_VERSION_PATCH@
+#define @HEADER_PREFIX@_VERSION ((@HEADER_VERSION_MAJOR@<<16)|(@HEADER_VERSION_MINOR@<<8)|(@HEADER_VERSION_PATCH@))
 
 #endif