Add ecm_generate_dbus_service_file

Summary:
It serves as a replacement for `kdbusaddons_generate_dbus_service_file`.

An application can be a DBus-activated service just fine without using KDBusAddons.
Moreover, this new module uses named arguments for future-proofing, and adds support for specifying a `SystemdService`.
It also cleans up the confusion on what the "path" is about: Rather than requiring to specify executable and path separately, we just extract the executable file name on Windows, if necessary.

Usage:
```
ecm_generate_dbus_service_file(NAME org.kde.kded5
                               EXECUTABLE ${KDE_INSTALL_FULL_BINDIR}/kded5
                               SYSTEMD_SERVICE plasma-kded)
```

Test Plan:
* Was able to generate a kded service file
* Was able to generate a kded service file with `SystemdUnit`
* Verified that it moaned when executable wasn't an absolute path
* Untested on Windwos

Reviewers: #frameworks, davidedmundson, kossebau, kfunk, habacker

Subscribers: kde-frameworks-devel, kde-buildsystem

Tags: #frameworks, #build_system

Differential Revision: https://phabricator.kde.org/D29051

7 files changed, 181 insertions, 0 deletions

diff --git a/docs/module/ECMGenerateDBusServiceFile.rst b/docs/module/ECMGenerateDBusServiceFile.rst
new file mode 100644
index 00000000..6d8385c7
--- /dev/null
+++ b/docs/module/ECMGenerateDBusServiceFile.rst
@@ -0,0 +1 @@
+.. ecm-module:: ../../modules/ECMGenerateDBusServiceFile.cmake
diff --git a/modules/ECMGenerateDBusServiceFile.cmake b/modules/ECMGenerateDBusServiceFile.cmake
new file mode 100644
index 00000000..f8b36d4f
--- /dev/null
+++ b/modules/ECMGenerateDBusServiceFile.cmake
@@ -0,0 +1,120 @@
+#.rst:
+# ECMGenerateDBusServiceFile
+# ---------------------------
+#
+# This module provides the ``ecm_generate_dbus_service_file`` function for
+# generating and installing a D-Bus service file.
+#
+# ::
+#
+#   ecm_generate_dbus_service_file(
+#       NAME <service name>
+#       EXECUTABLE <executable>
+#       [SYSTEMD_SERVICE <systemd service>]
+#       DESTINATION <install_path>
+#   )
+#
+# A D-Bus service file ``<service name>.service`` will be generated and installed
+# in the relevant D-Bus config location.
+#
+# ``<executable>`` must be an absolute path to the installed service executable. When using it with
+# ``KDEInstallDirs`` it needs to be the ``_FULL_`` variant of the path variable.
+#
+# Note: On Windows, the macro will only use the file name part of ``<executable>`` since D-Bus
+# service executables are to be installed in the same directory as the D-Bus daemon.
+#
+# Optionally, a ``<systemd service>`` can be specified to launch the corresponding
+# systemd service instead of the ``<executable>`` if the D-Bus daemon is started by systemd.
+#
+# Example usage:
+#
+# .. code-block:: cmake
+#
+#   ecm_generate_dbus_service_file(
+#       NAME org.kde.kded5
+#       EXECUTABLE ${KDE_INSTALL_FULL_BINDIR}/kded5
+#       DESTINATION ${KDE_INSTALL_DBUSSERVICEDIR}
+#   )
+#
+# .. code-block:: cmake
+#
+#   ecm_generate_dbus_service_file(
+#       NAME org.kde.kded5
+#       EXECUTABLE ${KDE_INSTALL_FULL_BINDIR}/kded5
+#       SYSTEMD_SERVICE plasma-kded.service
+#       DESTINATION ${KDE_INSTALL_DBUSSERVICEDIR}
+#   )
+#
+# Since 5.73.0.
+
+#=============================================================================
+# Copyright 2020 Kai Uwe Broulik <kde@broulik.de>
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+#
+# 1. Redistributions of source code must retain the copyright
+#    notice, this list of conditions and the following disclaimer.
+# 2. Redistributions in binary form must reproduce the copyright
+#    notice, this list of conditions and the following disclaimer in the
+#    documentation and/or other materials provided with the distribution.
+# 3. The name of the author may not be used to endorse or promote products
+#    derived from this software without specific prior written permission.
+#
+# THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
+# IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
+# OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
+# IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
+# INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
+# NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+# DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+# THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+# (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
+# THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
+
+include(CMakeParseArguments)
+
+function(ecm_generate_dbus_service_file)
+    set(options)
+    set(oneValueArgs EXECUTABLE NAME SYSTEMD_SERVICE DESTINATION)
+    set(multiValueArgs)
+    cmake_parse_arguments(ARG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+    if(ARG_UNPARSED_ARGUMENTS)
+        message(FATAL_ERROR "Unexpected arguments to ecm_generate_dbus_service_file: ${ARG_UNPARSED_ARGUMENTS}")
+    endif()
+    if(NOT ARG_NAME)
+        message(FATAL_ERROR "Missing NAME argument for ecm_generate_dbus_service_file")
+    endif()
+    if(NOT ARG_EXECUTABLE)
+        message(FATAL_ERROR "Missing EXECUTABLE argument for ecm_generate_dbus_service_file")
+    endif()
+    if(NOT ARG_DESTINATION)
+        message(FATAL_ERROR "Missing DESTINATION argument for ecm_generate_dbus_service_file")
+    endif()
+
+    if(WIN32)
+        get_filename_component(_exec "${ARG_EXECUTABLE}" NAME)
+    else()
+        if (NOT IS_ABSOLUTE ${ARG_EXECUTABLE})
+            message(FATAL_ERROR "EXECUTABLE must be an absolute path in ecm_generate_dbus_service_file")
+        else()
+            set(_exec ${ARG_EXECUTABLE})
+        endif()
+    endif()
+
+    set(_service_file ${CMAKE_CURRENT_BINARY_DIR}/${ARG_NAME}.service)
+
+    file(WRITE ${_service_file}
+    "[D-BUS Service]
+Name=${ARG_NAME}
+Exec=${_exec}
+")
+
+    if (ARG_SYSTEMD_SERVICE)
+        file(APPEND ${_service_file} "SystemdService=${ARG_SYSTEMD_SERVICE}\n")
+    endif()
+
+    install(FILES ${_service_file} DESTINATION ${ARG_DESTINATION})
+endfunction()
diff --git a/tests/CMakeLists.txt b/tests/CMakeLists.txt
index e61d7aa4..866df5bb 100644
--- a/tests/CMakeLists.txt
+++ b/tests/CMakeLists.txt
@@ -211,3 +211,11 @@ add_test_macro(ECMConfiguredInstallTest
     ${CMAKE_COMMAND} -P "${CMAKE_CURRENT_BINARY_DIR}/ECMConfiguredInstallTest/check_tree.cmake"
 )
 
+set(ECMGenerateDBusServiceFileTest_EXTRA_OPTIONS
+    --build-target install
+    --build-options
+        "-DCMAKE_INSTALL_PREFIX:PATH=${CMAKE_CURRENT_BINARY_DIR}/ECMGenerateDBusServiceFileTest/InstallDirectory"
+)
+add_test_macro(ECMGenerateDBusServiceFileTest
+    ${CMAKE_COMMAND} -P "${CMAKE_CURRENT_BINARY_DIR}/ECMGenerateDBusServiceFileTest/check_tree.cmake"
+)
diff --git a/tests/ECMGenerateDBusServiceFileTest/CMakeLists.txt b/tests/ECMGenerateDBusServiceFileTest/CMakeLists.txt
new file mode 100644
index 00000000..426ada89
--- /dev/null
+++ b/tests/ECMGenerateDBusServiceFileTest/CMakeLists.txt
@@ -0,0 +1,25 @@
+cmake_minimum_required(VERSION 3.5)
+project(ECMGenerateDBusServiceFileTest)
+set(CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/../../modules)
+
+# make sure the test install dir is clean
+file(REMOVE_RECURSE "${CMAKE_INSTALL_PREFIX}")
+include(ECMGenerateDBusServiceFile)
+
+# run test
+
+ecm_generate_dbus_service_file(
+   NAME org.kde.kded5
+   EXECUTABLE /usr/bin/kded5
+   DESTINATION ${CMAKE_INSTALL_PREFIX}/test
+)
+
+ecm_generate_dbus_service_file(
+   NAME org.kde.kded5.withSystemD
+   EXECUTABLE /usr/bin/kded5
+   SYSTEMD_SERVICE plasma-kded.service
+   DESTINATION ${CMAKE_INSTALL_PREFIX}/test
+)
+
+# this will be run by CTest
+configure_file(check_tree.cmake.in "${CMAKE_CURRENT_BINARY_DIR}/check_tree.cmake" @ONLY)
diff --git a/tests/ECMGenerateDBusServiceFileTest/check_tree.cmake.in b/tests/ECMGenerateDBusServiceFileTest/check_tree.cmake.in
new file mode 100644
index 00000000..c5fe51c9
--- /dev/null
+++ b/tests/ECMGenerateDBusServiceFileTest/check_tree.cmake.in
@@ -0,0 +1,20 @@
+set(EXPECTED "@CMAKE_CURRENT_SOURCE_DIR@/expected")
+set(ACTUAL "@CMAKE_INSTALL_PREFIX@")
+
+# Compares files in two directories, emits a fatal error if the top level files are different
+# Takes a directory of expected files, and a directory of output files
+function(compare_dirs expected output )
+    file(GLOB files "${expected}/*")
+    foreach(file ${files})
+        get_filename_component(name ${file} NAME)
+
+        execute_process(COMMAND ${CMAKE_COMMAND} -E compare_files ${file} "${output}/${name}"
+                                        RESULT_VARIABLE test_result
+        )
+        If (NOT test_result EQUAL 0)
+            message(FATAL_ERROR "Test failed: ${file} doesn't match ${output}/${name}!")
+        endif()
+    endforeach()
+endfunction()
+
+compare_dirs(${EXPECTED} ${ACTUAL}/test )
diff --git a/tests/ECMGenerateDBusServiceFileTest/expected/org.kde.kded5.service b/tests/ECMGenerateDBusServiceFileTest/expected/org.kde.kded5.service
new file mode 100644
index 00000000..a8d1a4bf
--- /dev/null
+++ b/tests/ECMGenerateDBusServiceFileTest/expected/org.kde.kded5.service
@@ -0,0 +1,3 @@
+[D-BUS Service]
+Name=org.kde.kded5
+Exec=/usr/bin/kded5
diff --git a/tests/ECMGenerateDBusServiceFileTest/expected/org.kde.kded5.withSystemD.service b/tests/ECMGenerateDBusServiceFileTest/expected/org.kde.kded5.withSystemD.service
new file mode 100644
index 00000000..bd0dd0ce
--- /dev/null
+++ b/tests/ECMGenerateDBusServiceFileTest/expected/org.kde.kded5.withSystemD.service
@@ -0,0 +1,4 @@
+[D-BUS Service]
+Name=org.kde.kded5.withSystemD
+Exec=/usr/bin/kded5
+SystemdService=plasma-kded.service